システムエンジニア技術ノート

;======================================================
;teratermマクロ
;sqlplusで接続して特定テーブル参照をし続けるマクロ
;
;参照するテーブルの検索キーは変数指定です。
;コマンドファイル実行前に、デフォルトで最初に実行したい
;コマンドも記載可能
;ログを自動で取得します。
;======================================================

;-----------------------------------------------------------
;初期設定
;-----------------------------------------------------------

;ログ自動保存
;ログ保存先
LOGSPATH = 'C:\test\log\'

;ログファイル名
getdate LOG_NAME 'teraterm(&h)_%Y%m%d_%H%M%S.log'

FULLPATH = LOGSPATH
strconcat FULLPATH LOG_NAME

;ログ取得開始
logopen FULLPATH 1 1

;タイトル設定
settitle 'sqlplusでテーブル参照をし続けるマクロ'

;プロンプト
wait_prompt = 'SQL>'

;ポーズタイム(s)
pause_time = 3

;参照するテーブルの検索キー
code_str = '> 300'
name_str = "like '%ナ%'" ;文字列に「'」を使用したいので「"」を使用した。

;-----------------------------------------------------------
;デフォルトで最初に実行したいコマンド
;-----------------------------------------------------------

default_input = 1 ;無ければ0にする

if default_input = 1 then
sendln 'date'
sendln 'whoami'
sendln 'hostname'
sendln 'pwd'
endif

;-----------------------------------------------------------
;sqlplusで接続し、初期設定
;-----------------------------------------------------------
sendln 'sqlplus xxx/xxx'
pause 1

sendln 'set linesize 3000'
pause 1

sendln 'set pages 100'
pause 1

;-----------------------------------------------------------
;テーブル参照し続ける
;-----------------------------------------------------------
;実行回数
count = 1

while 1
;10回毎に実行回数を表示する
if count % 10 = 0 then
;実行回数を表示する
int2str count_str count ;数値を文字に変換
sendln '###' count_str ' 回目を実行します ###'

;タイムスタンプ
sendln '!date'
pause 1

endif

;テーブル参照1
sendln 'select * from fruit where code ' code_str ' order by code;'

;プロンプト出力を待つ
wait wait_prompt

;指定時間ポーズする
pause pause_time

;テーブル参照2
sendln 'select * from fruit where name ' name_str ' order by code;'

;プロンプト出力を待つ
wait wait_prompt

;指定時間ポーズする
pause pause_time

count = count + 1
endwhile

:breakloop

;---END---