import flash.events.*;		/* マウスイベント等の各種イベントを扱うのに必要 */

import flash.media.*;		/* 音楽を再生するのに必要 */

import flash.net.URLRequest;	/* URL指定で音楽ファイルを読み込むために必要 */

import flash.geom.Rectangle;	/* 音量コントロールでマウスドラッグによる制御をするために必要 */



var CenterX = new Array();

CenterX[0] = 45;		/* 左数字のX座標 */

CenterX[1] = 80;		/* 中数字のX座標 */

CenterX[2] = 115;		/* 右数字のX座標 */



var CenterY:int = 45;		/* 数字の中心Y座標（７の初期位置であり、ストップボタンを押した時に止まる位置でもある） */

var Far:int = 22;		/* 隣り合う数字と数字の上下の距離 */

var Frame:int = 11;		/* １フレームで移動する距離（回転速度になる。これは上のFarを割り切れる数字にしないと止まらなくなる） */

var StartFlg:Boolean = false;	/* スロット開始レバーが引かれたかどうか判断するフラグ（true：引かれた「プレイ中」、false：引かれてない「未プレイ」） */



/* 左・中・右の停止ボタンがそれぞれ押されたかどうか判断するフラグ（true：押された、false：押されてない） */

var StopFlg = new Array();

StopFlg[0] = StopFlg[1] = StopFlg[2] = false;



/* 左・中・右の数字がそれぞれ停止完了しているかどうか判断するフラグ（true：停止完了、false：停止未完） */

var StopCmp = new Array();

StopCmp[0] = StopCmp[1] = StopCmp[2] = false;	



var VolumeLeft:int = 118;	/* 音量スライダーの左端X座標 */

var VolumeY:int = 93;		/* 音量スライダーのY座標 */

var VolumeLange:int = 26;	/* 音量スライダーの幅 */

var Volume:Number = 0.5;	/* 音量（初期値を入れておく。音量は０．０〜１．０の小数） */

var Ret = new Array();		/* 止まって確定した数字を保持する配列 */



/* 音量制御のためのオブジェクトを作成 */

var VolumeCtrl:SoundTransform = new SoundTransform();



/* スロット開始レバーの効果音設定（URLは使いたい音源ファイル（mp3のみ再生できます）のアドレスにして下さい） */

var LeverSoundChannel:SoundChannel;

var LeverSoundURL = new URLRequest("http://www.netriver.jp/chatriver/slot_sound/chikidonga.mp3");

var LeverSound:Sound = new Sound(LeverSoundURL);



/* スロット停止ボタンの効果音設定（URLは使いたい音源ファイル（mp3のみ再生できます）のアドレスにして下さい） */

var BtnSoundChannel:SoundChannel;

var BtnSoundURL = new URLRequest("http://www.netriver.jp/chatriver/slot_sound/bsyun.mp3");

var BtnSound:Sound = new Sound(BtnSoundURL);



/* スロット回転中のミュージック設定（URLは使いたい音源ファイル（mp3のみ再生できます）のアドレスにして下さい） */

var PlaySoundChannel:SoundChannel;

var PlaySoundURL = new URLRequest("http://www.netriver.jp/chatriver/slot_sound/loop03.mp3");

var PlaySound:Sound = new Sound(PlaySoundURL);

/* 一瞬再生して、オブジェクトを作っておく */

PlaySoundChannel = PlaySound.play(0,1);

PlaySoundChannel.stop();



var num = new Array();		/* 数字オブジェクトを格納する配列（２次元配列・１次元目の定義） */



/* 数字の左・中・右で３回ループ */

for ( var n:int = 0; n <= 2; n++ )

{

	num[n] = new Array();	/* 数字オブジェクトを格納する配列（２次元配列・２次元目の定義） */



	/* 数字の数ループ（０〜９） */

	for( var i:int = 0; i <= 9; i++ )

	{

		/* 左側数字 */

		if( n == 0 ) {

			/* 予めfrimo3で全数字の画像を取り込み、それら全てに対して「シンボルに変換」を適用し、ムービークリップに変換しておく。 */

			/* シンボルに変換したインスタンス名を「num10」〜「num19」としておき、ここで扱いやすいようにnumという配列に格納する。 */

			if( i == 0 ) { num[n][i] = num10; }

			else if( i == 1 ) { num[n][i] = num11; }

			else if( i == 2 ) { num[n][i] = num12; }

			else if( i == 3 ) { num[n][i] = num13; }

			else if( i == 4 ) { num[n][i] = num14; }

			else if( i == 5 ) { num[n][i] = num15; }

			else if( i == 6 ) { num[n][i] = num16; }

			else if( i == 7 ) { num[n][i] = num17; }

			else if( i == 8 ) { num[n][i] = num18; }

			else if( i == 9 ) { num[n][i] = num19; }



		/* 中の数字 */

		} else if( n == 1 ) {

			/* 予めfrimo3で全数字の画像を取り込み、それら全てに対して「シンボルに変換」を適用し、ムービークリップに変換しておく。 */

			/* シンボルに変換したインスタンス名を「num10」〜「num19」としておき、ここで扱いやすいようにnumという配列に格納する。 */

			if( i == 0 ) { num[n][i] = num20; }

			else if( i == 1 ) { num[n][i] = num21; }

			else if( i == 2 ) { num[n][i] = num22; }

			else if( i == 3 ) { num[n][i] = num23; }

			else if( i == 4 ) { num[n][i] = num24; }

			else if( i == 5 ) { num[n][i] = num25; }

			else if( i == 6 ) { num[n][i] = num26; }

			else if( i == 7 ) { num[n][i] = num27; }

			else if( i == 8 ) { num[n][i] = num28; }

			else if( i == 9 ) { num[n][i] = num29; }



		/* 右側数字 */

		} else if( n == 2 ) {

			/* 予めfrimo3で全数字の画像を取り込み、それら全てに対して「シンボルに変換」を適用し、ムービークリップに変換しておく。 */

			/* シンボルに変換したインスタンス名を「num10」〜「num19」としておき、ここで扱いやすいようにnumという配列に格納する。 */

			if( i == 0 ) { num[n][i] = num30; }

			else if( i == 1 ) { num[n][i] = num31; }

			else if( i == 2 ) { num[n][i] = num32; }

			else if( i == 3 ) { num[n][i] = num33; }

			else if( i == 4 ) { num[n][i] = num34; }

			else if( i == 5 ) { num[n][i] = num35; }

			else if( i == 6 ) { num[n][i] = num36; }

			else if( i == 7 ) { num[n][i] = num37; }

			else if( i == 8 ) { num[n][i] = num38; }

			else if( i == 9 ) { num[n][i] = num39; }

		}

	}



	/* ここで、各数字インスタンスのX座標・Y座標の初期値を設定する */



	var now_pos:int = CenterY + ( Far * 7 );	/* 現在のY座標（０の初期Y座標になる「７を初期値にしたいため、０はY軸中心座標より数字７個分下に配置」） */



	/* 各数字ループ */

	for( i = 0; i <= 9; i++ ) {

		num[n][i].x = CenterX[n];		/* 数字インスタンスのX座標を設定する（ここで実際の配置が行われる。X座標は固定で、今後は動かさない） */

		num[n][i].y = now_pos;			/* 数字インスタンスのY座標を設定する（ここで実際の配置が行われる） */

		now_pos -= Far;				/* 現在のY座標を、数字と数字の間隔だけ上にずらす */

	}



	/* 全ての数字の配置は、以下のようなイメージになる */

	/* ９　９　９ */

	/* ８　８　８ */

	/* ７　７　７    ← ここが縦（Y座標）の中心に配置されるようにしている */

	/* ６　６　６ */

	/* ５　５　５ */

	/* ４　４　４ */

	/* ３　３　３ */

	/* ２　２　２ */

	/* １　１　１ */

	/* ０　０　０ */

}



/* イベントリスナー登録（これをやっておくと、すぐ下に定義してあるNumberRolling関数が実行され続けるようです） */

stage.addEventListener(Event.ENTER_FRAME, NumberRolling);



/* 数字を回転させる関数（本当は上から下に移動してるだけ。ある程度下に行ったら上に戻してまた下に移動させる。この関数は常に実行され続ける） */

function NumberRolling(event:Event):void {

	if( StartFlg == false ){ return; }	/* スロット開始レバーが引かれていなければ処理しないでリターン */



	/* スロット開始レバーが引かれていれば、以下で回転処理をする。 */

	/* 左・中・右の数字ループ */

	for( n = 0; n <= 2; n++ ) {



		/* ストップボタンが押されていなければ、回転させる。 */

		if( StopFlg[n] == false ) {



			/* 数字ループしてそれぞれを１フレーム分下にずらす */

			for( i = 0; i <= 9; i++ ) {

				num[n][i].y += Frame;



				/* ずらした後、数字８個分下まで行ってしまったら、数字２個分上に再配置する。 */

				if( num[n][i].y == CenterY + ( Far * 8 ) ) {

					num[n][i].y = CenterY - ( Far * 2 );

				}

			}



		/* ストップボタンが押されていて、停止が完了していない時は以下で停止処理をする。 */

		} else if( StopCmp[n] == false ) {



			StopCmp[n] = true;	/* 停止完了状態にする */



			/* ストップ処理関数を呼び、その戻り値でどの数字が止まったかを保持。 */

			/* （チャットではこの数字をJavaScriptに渡して結果をHTMLに反映しているが、ここではJavaScriptと連携） */

			/* （しないので、Ret[n]に保持する必要はない。） */

			Ret[n] = Stop(n);	



			/* 左・中・右の全ての数字が止まったら */

			if( StopCmp[0] == true && StopCmp[1] == true && StopCmp[2] == true ) {

				StartFlg = false;	/* スロット開始レバーが押されていない状態にする（再プレイ可能にする） */

				PlaySoundChannel.stop();/* プレイ中のミュージックを止める */

				/* チャットではここでJavaScriptに３つの数字を渡す */

			}

		}

	}

}

/* ここは各オブジェクトに対してマウスがクリックされた時の動作（呼び出す関数）を設定する */

start_btn.addEventListener(MouseEvent.MOUSE_DOWN, StartBtn);		/* スロット開始レバーが引かれたらStartBtn関数を呼ぶ設定 */

stop1.addEventListener(MouseEvent.MOUSE_DOWN, Stop1);			/* ストップボタン（左）が押されたらStop1関数を呼ぶ設定 */

stop2.addEventListener(MouseEvent.MOUSE_DOWN, Stop2);			/* ストップボタン（中）が押されたらStop2関数を呼ぶ設定 */

stop3.addEventListener(MouseEvent.MOUSE_DOWN, Stop3);			/* ストップボタン（右）が押されたらStop3関数を呼ぶ設定 */

volume_ctl.addEventListener(MouseEvent.MOUSE_DOWN, VolumeChange1);	/* 音量スライダーがクリックされたらVolumeChange1を呼ぶ設定 */

volume_pos1.addEventListener(MouseEvent.MOUSE_DOWN, VolumeChange2);	/* ボリューポインタがクリックされたらVolumeChange2を呼ぶ設定 */



/* スロット開始レバーが引かれた時に呼び出される関数 */

function StartBtn(event:MouseEvent):void {

	if( StartFlg == true ){ return; }				/* 既に引かれている場合（プレイ中）は処理しないでリターンする */

	VolumeCtrl.volume = Volume;					/* 効果音・プレイミュージックの音量をコントロールオブジェクトに設定 */

	LeverSoundChannel = LeverSound.play(0,1);			/* スロット開始レバーの効果音を再生 */

	LeverSoundChannel.soundTransform = VolumeCtrl;			/* スロット開始レバー効果音の音量を設定 */

	PlaySoundChannel = PlaySound.play(0,99);			/* プレイミュージックを再生 */

	PlaySoundChannel.soundTransform = VolumeCtrl;			/* プレイミュージックの音量を設定 */

    StopFlg[0] = StopFlg[1] = StopFlg[2] = false;			/* 停止ボタンフラグを初期化する（各ボタンが押されていない状態にする） */

    StopCmp[0] = StopCmp[1] = StopCmp[2] = false;			/* 停止完了フラグを初期化する（各数字が停止完了していない状態にする） */

    StartFlg = true;							/* スロット開始レバーが引かれた状態（プレイ中）にする */

}



/* ストップボタン（左）が押された時に呼び出される関数 */

function Stop1(event:MouseEvent):void {

	if( StartFlg == false ){ return; }				/* 未プレイ状態の時は処理しないでリターンする */

	if( StopFlg[0] == true ){ return; }				/* 既押されていた場合は処理しないでリターンする */

	VolumeCtrl.volume = Volume;					/* 効果音の音量をコントロールオブジェクトに設定 */

	BtnSoundChannel = BtnSound.play(0,1);				/* 停止ボタンの効果音を再生 */

	BtnSoundChannel.soundTransform = VolumeCtrl;			/* 停止ボタン効果音の音量を設定 */

    StopFlg[0] = true;							/* ストップボタン（左）が押された状態にする */

}



/* ストップボタン（中）が押された時に呼び出される関数 */

function Stop2(event:MouseEvent):void {

	if( StartFlg == false ){ return; }				/* 未プレイ状態の時は処理しないでリターンする */

	if( StopFlg[1] == true ){ return; }				/* 既押されていた場合は処理しないでリターンする */

	VolumeCtrl.volume = Volume;					/* 効果音の音量をコントロールオブジェクトに設定 */

	BtnSoundChannel = BtnSound.play(0,1);				/* 停止ボタンの効果音を再生 */

	BtnSoundChannel.soundTransform = VolumeCtrl;			/* 停止ボタン効果音の音量を設定 */

    StopFlg[1] = true;							/* ストップボタン（中）が押された状態にする */

}



/* ストップボタン（右）が押された時に呼び出される関数 */

function Stop3(event:MouseEvent):void {

	if( StartFlg == false ){ return; }				/* 未プレイ状態の時は処理しないでリターンする */

	if( StopFlg[2] == true ){ return; }				/* 既押されていた場合は処理しないでリターンする */

	VolumeCtrl.volume = Volume;					/* 効果音の音量をコントロールオブジェクトに設定 */

	BtnSoundChannel = BtnSound.play(0,1);				/* 停止ボタンの効果音を再生 */

	BtnSoundChannel.soundTransform = VolumeCtrl;			/* 停止ボタン効果音の音量を設定 */

    StopFlg[2] = true;							/* ストップボタン（右）が押された状態にする */

}



/* ストップ処理関数 */

/* 実際はストップボタンが押されたタイミングで回転は止まるが、微妙な位置で止まっている場合に */

/* 微調整してぴったり真ん中で止めるための関数 */

/* 引数の「n」は０〜２（左・中・右）のどれか。指定された列の数字を微調整停止させる */

function Stop( n:int ):int {

	var ret:int = 100;		/* 戻り値（回転している数字の最大値より大きい数字を適当に設定） */



	/* 無限ループ */

	while(1) {



		/* 数字０〜９ループ */

		for( i = 0; i <= 9; i++ ) {

			num[n][i].y += Frame;



			/* 数字８個分下にずれたら、数字２個分上に最配置 */

			if( num[n][i].y == CenterY + ( Far * 8 ) ) {

				num[n][i].y = CenterY - ( Far * 2 );

			}

			/* この数字が丁度真ん中に止まっていたら、戻り値にその数字を入れる（これで無限ループを抜ける） */

			/* ここではすぐループを抜けずに、次回実行のために後ろの数字の位置を全部下にずらしておく（９まで全部ループさせる） */

			if( num[n][i].y == CenterY ) {

				ret = i;

			}

		}



		/* 上のループで戻り値に９以下の数字が入ったら、無限ループを抜ける */

		if( ret <= 9 ) {

			break;

		}

	}

	return( ret );

}



/* 音量スライダーがクリックされた時に呼び出される関数 */

function VolumeChange1(event:MouseEvent):void {

	volume_pos1.x = stage.mouseX;					/* 音量ポインタの位置をマウスの位置に設定 */

	Volume = ( volume_pos1.x - VolumeLeft ) / VolumeLange;		/* 音量ポインタの位置により、音量を設定（０.０〜１．０の間の小数で設定する） */

	VolumeCtrl.volume = Volume;											/* コントロールオブジェクトの音量に設定 */

	PlaySoundChannel.soundTransform = VolumeCtrl;			/* プレイミュージックのみリアルタイムに音量を設定する */



	/* 音量ポインタのドラッグを開始*/

	/* Rectangleの引数は、ポインタ位置の制御（ポインタの左端、ポインタの上端、ポインタ左右の長さ、ポインタ上下の長さ） */

	volume_pos1.startDrag(false, new Rectangle(VolumeLeft, VolumeY, VolumeLange, 0));



	stage.addEventListener(MouseEvent.MOUSE_UP, xMouseUp);		/* マウスアップ時にxMouseUp関数が呼ばれるように設定 */

	volume_pos1.addEventListener(MouseEvent.MOUSE_MOVE, xMouseMove);/* マウス移動時にxMouseMove関数が呼ばれるように設定 */

}



/* 音量ポインタがクリックされた時に呼び出される関数 */

function VolumeChange2(event:MouseEvent):void {

	/* 音量ポインタのドラッグを開始*/

	/* Rectangleの引数は、ポインタ位置の制御（ポインタの左端、ポインタの上端、ポインタ左右の長さ、ポインタ上下の長さ） */

	volume_pos1.startDrag(false, new Rectangle(VolumeLeft, VolumeY, VolumeLange, 0));



	stage.addEventListener(MouseEvent.MOUSE_UP, xMouseUp);		/* マウスアップ時にxMouseUp関数が呼ばれるように設定 */

	volume_pos1.addEventListener(MouseEvent.MOUSE_MOVE, xMouseMove);/* マウス移動時にxMouseMove関数が呼ばれるように設定 */

}



/* 音量スライダーもしくはポインタでマウスアップされた時に呼び出される関数 */

function xMouseUp(evt:MouseEvent):void {

	volume_pos1.stopDrag();						/* 音量ポインタのドラッグを停止 */

	stage.removeEventListener(MouseEvent.MOUSE_UP, xMouseUp);	/* マウスアップ時のイベントリスナーを解除*/

	volume_pos1.removeEventListener(MouseEvent.MOUSE_MOVE, xMouseMove);/* マウス移動時のイベントリスナーを解除*/

}



/* 音量スライダーもしくはポインタでマウスが移動された時に呼び出される関数 */

function xMouseMove(evt:MouseEvent):void {

	Volume = ( volume_pos1.x - VolumeLeft ) / VolumeLange;		/* 音量ポインタの位置により、音量を設定（０.０〜１．０の間の小数で設定する） */

	VolumeCtrl.volume = Volume;					/* コントロールオブジェクトの音量に設定 */

	PlaySoundChannel.soundTransform = VolumeCtrl;			/* プレイミュージックのみリアルタイムに音量を設定する */

}